空間數據可視化之spmap命令

各位小夥伴、大夥伴大家好，我爬蟲俱樂部「張三丰」又回來啦~

1. 導讀

2. 語法及其簡單應用spmap是一個外部命令，首先我們需要安裝該命令：

ssc install spmap

spmap [attribute] [if] [in] using basemap [, ///
            basemap_options ///
            polygon(polygon_suboptions) ///
            line(line_suboptions) ///
            point(point_suboptions) ///
            diagram(diagram_suboptions) ///
            arrow(arrow_suboptions) ///
            label(label_suboptions) ///
            scalebar(scalebar_suboptions) ///
            graph_options]

spmap的語法可以分為三層，spmap也是通過疊加這三個圖層來實現繪圖的。

第一層：底層地圖(basemap)。代表由多個子區域組合而成研究區域，如在世界地圖中，各個國家和地區即為該地圖的子區域。在Stata中，構造底層地圖的數據集(countries_cor.dta)結構如下圖所示：

其中，_ID是標識變量，_X和_Y是用於橫、縱坐標，對於每個子區域（如，中國）都擁有成百上千對(_X,_Y)來構造該區域的形狀。我們來看一下世界地圖的輪廓。

cd D:\sus_part3\data
use countries_cor.dta,clear
scatter _Y _X,msize(vtiny)

該層還可以設置[attribute]選項，該選項是在使用spmap命令時，位於master數據集中的一個數值型變量，比如各國在Sus上的發文總量(SUM)。我們通過設置漸變色來直觀地展示世界主要國家和地區的發文情況。

use draw_dbf.dta,clear //master數據集包含了[attribute]變量SUM
spmap SUM using countries_cor.dta, ///
id(_ID) clmethod(custom) /// **設置標識變量，分級類型為用戶自設**/
clbreaks(0 100 500 1000 2000 3000 5000 13000) fcolor(Reds2) /**設置分段，設置漸變色為紅色漸變**/

第二層：根據研究需要，我們可以在底層地圖上添加各種空間對象(spatial objects)。目前，spmap命令有6種空間對象可供選擇，分別是多邊形(polygon)、點(point)、線(line)、箭頭(arrow)和標籤(label)。比如，現在我們想突出顯示美國這個子區域：

**從世界地圖中將構建美國區域的坐標對另存為USA_cor.dta**
use countries_cor.dta,clear
keep if _ID==252
save USA_cor.dta,replace

use draw_dbf.dta,clear
**第一層，底層地圖**
spmap SUM using countries_cor.dta, ///
id(_ID) clmethod(custom) ///
clbreaks(0 100 500 1000 2000 3000 5000 13000) fcolor(Reds2) /// **第二層，突出顯示美國區域，藍色填充，輪廓線粗細適中**/
polygon(data(USA_cor.dta) fcolor(blue) osize(medthin))

use draw_dbf.dta,clear
**第一層：底層地圖**
spmap using countries_cor.dta, id(_ID) /// **第二層：在底層地圖上描點，world_point.dta包含了描點的坐標xcoord和ycoord變量**/
point(data(world_point.dta) xcoord(xcoord) ycoord(ycoord) /// **第二層美化：設置比例變量為SUM，填充顏色為彩虹色**/
proportional(SUM) shape(o) size(large) by(_ID) fcolor(Rainbow))

第三層：根據自身的需要，我們可以在第一、第二層上添加更多元素(elements)，比如比例尺(scalebar)、標題(title)、注釋(note)、圖例(legend)等。

use draw_dbf.dta,clear
**第一層：底層地圖**
spmap SUM using countries_cor.dta, ///
id(_ID) clmethod(custom) ///
clbreaks(0 100 500 1000 2000 3000 5000 13000) fcolor(Reds2) ///
polygon(data(USA_cor.dta) fcolor(blue) osize(medthin)) /// **第二層：突出顯示美國子區域**/
title("世界主要國家和地區在Sustainability發表論文的數量",size(*1.2)) subtitle("Jan.2009-Sep.2020",size(*0.8)) /// **第三層：添加圖例、標題等其他元素**/
graphregion(margin(medium)) ///
note("Source:爬蟲俱樂部整理")

3. 關鍵點

綜合來看，使用spmap作圖有兩大難點。

（1）獲取坐標數據集難

在第二部分的簡單應用中，我們所用到的坐標數據集有：countries_cor.dta：世界國家級地圖坐標數據集，是使用shp2dta命令轉換countries.shp文件而來。而.shp由ESRI（Environmental Systems Research Institute)開發的shape文件，一個shape文件包括一個主文件，一個索引文件，和一個dBASE表。其中主文件的後綴就是.shp。

簡單來說，shape文件是美國一家地理信息系統技術公司製作的坐標數據文件，我們可以使用Stata的外部命令shp2dta將該文件轉換為dta文件。shape文件可以在某度搜索，關鍵詞為「中國 shapefile」，或者從https://gadm.org/data.html下載。轉換命令為：

ssc install shp2dta
shp2dta using countries.shp, ///
database("countries_dbf") coordinates("countries_cor")

USA_cor.dta：美國地圖坐標數據集。從countries_cor.dta中提取的_ID為252（代表美國）的坐標對。world_point.dta：描點坐標數據集。該數據集包括發文量top10的國家的坐標對（每個國家只需要一組，一般是該國的首都經緯度），因為數據量比較小，所以本勞模手工查找了這些國家首都的經緯度，如果數據量比較大，也可以在某度中搜索，關鍵詞為「世界各國經緯度表」。（2）理解master數據集和各坐標數據集的關係難
master數據集和各坐標數據集的關係確實一時難以理解，但肯定比《紅樓夢》的人物關係簡單。

圖中方框為數據集文件，圓圈代表對應的變量。其中的難點是，如何將master（我們自己的研究數據集）與basemap建立聯結？可以看到，我們是通過countries_dbf.dta文件來建立聯結的。countries_dbf.dta文件是轉換countries.shp而來的文件之一，其數據結構為：

我們自己的研究數據集draw_dbf的數據結構為：

對比以上兩個數據集，我們發現它們有相同的變量NAME，因此我們將兩者橫向合併：

use draw_dbf.dta,clear
merge 1:1 NAME using countries_dbf.dta,keepusing(_ID)

這樣，我們就通過_ID標識變量將master數據集與basemap數據集聯結起來了。這也給我們一個提示：在整理自己的數據集(master)時應儘可能使每個觀測對象的名稱(NAME，比如國家名稱、省市名稱等)與countries_dbf.dta中一致。

本文用到的所有數據集均可通過後臺回復spmap獲取，快去打開Stata試試看吧~