小夥伴們
平常工作上肯定會遇到困惑，經常會通過一些方式來提高工作效率，比如運用函數
但通過百度查詢的，網上的有些函數公式過於複雜，不理解其用法，不知道怎麼用
今天，小編給大家分享一套萬能套用公式，工作有遇到，可以複製套用它，既省時，又省力
覺得有用，可以收藏，也可以分享給旁邊的朋友哦！
一、數字處理
① 絕對值設置：
=ABS(數字)
② 數字取整：
=INT(數字)
③ 數字四捨五入：
=ROUND(數字,小數位數)
二、判斷公式
① 怎麼把公式返回的錯誤值，顯示為空？
C2填入公式： =IFERROR(A2/B2,"")
說明：如果是錯誤值則顯示為空，否則正常顯示。
② IF的多條件判斷
C2 填入公式： =IF(AND(A2<500,B2="未到期"),"補款","")
說明：兩個條件同時成立用AND,任一個成立用OR函數。
三、統計公式
① 統計兩表重複值
B2填入公式：=COUNTIF(Sheet15!A:A,A2)
說明：如果返回值大於0說明在另一個表中存在，0則不存在。
② 統計年齡在30~40之間的員工個數
套用公式 =FREQUENCY(D2:D8,{40,29})
③ 統計不重複的總人數
C2填入公式：
=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))
備註：用COUNTIF統計出每人的出現次數，用1除的方式把出現次數變成分母，然後相加。
④ 按多條件統計平均值
F2套用公式：
=AVERAGEIFS(D:D,B:B,"財務",C:C,"大專")
⑤ 排名公式
=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))
備註：覺得這個複雜，這裡也可以運用公式，RANK來排名
四、求和公式
① 隔列求和
H3填入公式：
=SUMIF($A$2:$G$2,H$2,A3:G3)
或
=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)
說明：如果標題行沒有規則用第2個公式
②單條件求和
F2填入公式：
=SUMIF(A:A,E2,C:C)
備註： SUMIF函數的基本用法
③ 單條件模糊求和
公式：詳見下圖
說明：如果需要進行模糊求和，就需要掌握通配符的使用，其中星號是表示任意多個字符，如"*A*"就表示a前和後有任意多個字符，即包含A。
④ 多條求模糊求和
C11填入公式：
=SUMIFS(C2:C7,A2:A7,A11&"*",B2:B7,B11)
備註：在sumifs中可以使用通配符*
⑤ 多表相同位置求和
B2填入公式：
=SUM(Sheet1:Sheet19!B2)
備註：在表中間刪除或添加表後，公式結果會自動更新。
⑥ 按日期和產品求和
=SUMPRODUCT((MONTH($A$2:$A$25)=F$1)*($B$2:$B$25=$E2)*$C$2:$C$25)
備註：SUMPRODUCT可以完成多條件求和（多條求和，這個公式還是很智能）
五、查找與引用公式
① 單條件查找
=VLOOKUP(B11,$B$3:$F$7,4,FALSE)
備註：VLOOKUP查找的區域，注意要絕對引用，除非你選擇的是區域列。
② 雙向查找
公式填入：
=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))
備註：利用MATCH函數查找位置，用INDEX函數取值
③ 查找最後一個符合條件記錄
備註：0/(條件)可以把不符合條件的變成錯誤值，而lookup可以忽略錯誤值
④ 多條件查找
公式:詳見下圖
備註 : 同上一個公式原理一樣
⑤ 指定非空區域最後一個值查找
公式;詳見下圖
⑥ 區間取值
備註：VLOOKUP和LOOKUP函數都可以按區間取值，一定要注意，銷售量列的數字一定要升序排列。
六、字符串處理公式
① 多單元格字符合併
C2填入公式
=PHONETIC(A2:A7)
備註：Phonetic函數只能對字符型內容合併，數字不可以。
② 截取除後3位之外的部分
套用公式： =LEFT(D1,LEN(D1)-3)
備註：LEN計算出總長度,LEFT從左邊截總長度-3個
③ 截取 - 之前的部分
=Left(A1,FIND("-",A1)-1)
備註：用FIND函數查找位置，用LEFT截取。
④ 截取字符串中任一段
B1填入公式：
=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",20)),20,20))
備註: 公式是利用強插N個空字符的方式進行截取
⑤ 字符串查找
=IF(COUNT(FIND("河南",A2))=0,"否","是")
說明: FIND查找成功，返回字符的位置，否則返回錯誤值，而COUNT可以統計出數字的個數，這裡可以用來判斷查找是否成功。
⑥ 字符串查找一對多
套用公式：
=IF(COUNT(FIND({"遼寧","黑龍江","吉林"},A2))=0,"其他","東北")
備註：設置FIND第一個參數為常量數組，用COUNT函數統計FIND查找結果
七、日期計算公式
① 兩日期間隔的年、月、日計算
A1是開始日期（2011-12-1），B1是結束日期(2013-6-10)。計算：
相隔多少天？=datedif(A1,B1,"d") 結果：557
相隔多少月? =datedif(A1,B1,"m") 結果：18
相隔多少年? =datedif(A1,B1,"Y") 結果：1
不考慮年相隔多少月？=datedif(A1,B1,"Ym") 結果：6
不考慮年相隔多少天？=datedif(A1,B1,"YD") 結果：192
不考慮年月相隔多少天？=datedif(A1,B1,"MD") 結果：9
datedif函數第3個參數說明：
"Y" 時間段中的整年數。
"M" 時間段中的整月數。
"D" 時間段中的天數。
"MD" 天數的差。忽略日期中的月和年。
"YM" 月數的差。忽略日期中的日和年。
"YD" 天數的差。忽略日期中的年。
② 扣除周末的工作日天數
=NETWORKDAYS.INTL(IF(B2<date(2015,1,1),date(2015,1,1),b2),date(2015,1,31),11)< p="">
備註：返回兩個日期之間的所有工作日數，使用參數指示哪些天是周末，以及有多少天是周末。周末和任何指定為假期的日期不被視為工作日
八、其他常用公式：
① 創建工作表目錄的公式（這個日常工作中常用）
把所有的工作表名稱列出來，然後自動添加超連結，管理工作表就非常方便了。
使用方法：
第1步：在定義名稱中輸入公式：
=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(NOW())
第2步、在工作表中輸入公式並拖動，工作表列表和超連結已自動添加
=IFERROR(HYPERLINK("#'"&INDEX(Shname,ROW(A1))&"'!A1",INDEX(Shname,ROW(A1))),"")
② 中英文互譯公式
=FILTERXML(WEBSERVICE("http://fanyi.youdao.com/translate?&i="&A2&"&doctype=xml&version"),"//translation")
認識，是一種緣分
感謝生命中的每一次相遇
都是一種幸福！