Julia 語言包含了預定義的複數和有理數類型，並且支持它們的各種標準數學運算和初等函數。由於也定義了複數與分數的類型轉換與類型提升，因此對預定義數值類型（無論是原始的還是複合的）的任意組合進行的操作都會表現得如預期的一樣。
複數
在Julia 中, 全局常量「im」 被綁定到複數i，表示-1 的主平方根（不應使用數學家習慣的i 或工程師習慣的j 來表示此全局常量，因為它們是非常常用的索引變量名）。由於Julia 允許數值字面量作為係數與標識符並置，這種綁定就足夠為複數提供很方便的語法，類似於傳統的數學法：
julia> 1+2im
1 + 2im
你可以對複數進行各種標準算術操作，示例：
julia> (1 + 2im)*(2 - 3im)
8 + 1im
julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im
julia> (1 + 2im) + (1 - 2im)
2 + 0im
julia> (-3 + 2im) - (5 - 1im)
-8 + 3im
julia> (-1 + 2im)^2
-3 - 4im
julia> (-1 + 2im)^2.5
2.729624464784009 - 6.9606644595719im
julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im
julia> 3(2 - 5im)
6 - 15im
julia> 3(2 - 5im)^2
-63 - 60im
julia> 3(2 - 5im)^-1.0
0.20689655172413796 + 0.5172413793103449im
提升機制確保了不同類型的操作數的組合能夠正常工作:
julia> 2(1 - 1im)
2 - 2im
julia> (2 + 3im) - 1
1 + 3im
julia> (1 + 2im) + 0.5
1.5 + 2.0im
julia> (2 + 3im) - 0.5im
2.0 + 2.5im
julia> 0.75(1 + 2im)
0.75 + 1.5im
julia> (2 + 3im) / 2
1.0 + 1.5im
julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im
julia> 2im^2
-2 + 0im
julia> 1 + 3/4im
1.0 - 0.75im
注意：3/4im == 3/(4*im) == -(3/4*im)，因為係數比除法的優先級更高。
Julia 提供了一些操作複數的標準函數：
julia> z = 1 + 2im
1 + 2im
# z的實部
julia> real(1 + 2im)
1
# z的虛部
julia> imag(1 + 2im)
2
#z的共軛複數
julia> conj(1 + 2im) # complex conjugate of z
1 - 2im
#z的絕對值
julia> abs(1 + 2im) # absolute value of z
2.23606797749979
#平方後的絕對值
julia> abs2(1 + 2im) # squared absolute value
5
#相位角（以弧度為單位）
julia> angle(1 + 2im) # phase angle in radians
1.1071487177940904
通常，複數的絕對值（abs）是從零點到它的距離。abs2 給出絕對值的平方，作用於複數上時非常有用，因為它避免了取平方根。angle 返回以弧度為單位的相位角（也被稱為輻角函數）。所有其
它的初等函數在複數上也都有完整的定義：
julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im
julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im
julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991518im
julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im
julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im
注意數學函數通常應用於實數就返回實數值，應用於複數就返回複數值。例如，當sqrt 應用於-1與-1 + 0im 會有不同的表現，雖然-1 == -1 + 0im：
julia> sqrt(-1)
ERROR: DomainError with -1.0:
sqrt will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
Stacktrace:
[...]
julia> sqrt(-1 + 0im)
0.0 + 1.0im
從變量構建複數時，文本型數值係數記法不再適用。相反地，乘法必須顯式地寫出：
julia> a = 1; b = 2; a + b*im
1 + 2im
然而，我們並不推薦這樣做，而應改為使用更高效的complex 函數直接通過實部與虛部構建一個複數值：
julia> a = 1; b = 2; complex(a, b)
1 + 2im
這種結構避免了乘法和加法操作。
Inf和NaN在複數的實部和虛部傳播，如特殊浮點值部分所述:
julia> 1 + Inf*im
1.0 + Inf*im
julia> 1 + NaN*im
1.0 + NaN*im
有理數
Julia有一個有理數類型來表示整數的精確比例。使用//操作符構造有理函數,有理數的分子和分母如果有公因式，則可以化簡為最小項，使分母非負:
julia> 2//3
2//3
julia> 3//2
3//2
julia> 6//3
2//1
julia> 3//6
1//2
整數比率的規範化形式是唯一的，因此可以通過檢查分子和分母是否相等來測試有理值是否相等。有理值的標準化分子、分母可通過分子、分母函數提取:
julia> numerator(2//3)
2
julia> denominator(2//3)
3
分子和分母的直接比較通常是不必要的，因為標準算術和比較操作對分數值也有定義：
julia> 2//3 == 6//9
true
julia> 2//3 == 9//27
false
julia> 3//7 < 1//2
true
julia> 3//4 > 2//3
true
julia> 2//4 + 1//6
2//3
julia> 5//12 - 1//4
1//6
julia> 5//8 * 3//12
5//32
julia> 6//5 / 10//7
21//25
分數可以很容易地轉換成浮點數：
julia> float(3//4)
0.75
對任意整數值a 和b（除了a == 0 且b == 0 時），從分數到浮點數的轉換遵從以下的一致性：
julia> a = 1; b = 2;
julia> isequal(float(a//b), a/b)
true
Julia 接受構建無窮分數值：
julia> 5//0
1//0
julia> -3//0
-1//0
julia> typeof(ans)
Rational{Int64}
但不接受試圖構建一個NaN 分數值：
julia> 0//0
ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
Stacktrace:
[...]
像往常一樣，類型提升系統使得分數可以輕鬆地同其它數值類型進行交互：
julia> 3//5 + 1
8//5
julia> 3//5 - 0.5
0.09999999999999998
julia> 2//7 * (1 + 2im)
2//7 + 4//7*im
julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im
julia> 3//2 / (1 + 2im)
3//10 - 3//5*im
julia> 1//2 + 2im
1//2 + 2//1*im
julia> 1 + 2//3im
1//1 - 2//3*im
julia> 0.5 == 1//2
true
julia> 0.33 == 1//3
false
julia> 0.33 < 1//3
true
julia> 1//3 - 0.33
0.0033333333333332993