Excel中最值得珍藏的16個函數公式

今天蘭色分享的excel函數公式都不常用，但一旦遇到就會讓你感覺頭痛，只能到處提問和查找。今天蘭色把這些公式收集到一起。以備急時之需。

1、生成不重複隨機數公式

B2:(數組公式，按ctrl+shift+enter三鍵輸入)

=SMALL(IF(COUNTIF(B$1:B1,ROW($1:$10)),"",ROW($1:$10)),RANDBETWEEN(1,10-COUNT(B$1:B1)))

2、多區域排名公式

=RANK(B3,($B$3:$B$10,$E$3:$E$10,$H$3:$H$10))

3、提取唯一值公式

C2(數組公式按ctrl+shift+enter三鍵輸入)

=IFERROR(INDEX(A:A,SMALL(IF(MATCH(A$2:A$9,A$2:A$9,)=ROW($1:$8),ROW($2:$9)),ROW(A1))),"")

有一個簡單的

=INDEX(A:A,MATCH(0,COUNTIF(C$1:C1,A$1:A$99),0))&""

4、多區域超連結公式

=HYPERLINK("#C3:C10,F3:F10,I3:I10","總排名")

5、提取篩選後的內容

公式：（數組公式，按ctrl+shift+enter三鍵輸入）

=INDEX(B:B,MATCH(1,SUBTOTAL(3,OFFSET(B1,ROW(1:100),)),0)+1)

6、字符串拆分

B2

=TRIM(MID(SUBSTITUTE($A2,"-",REPT(" ",99)),99*COLUMN(A1)-98,99))

7、動態獲取A列最後一個數字

=LOOKUP(1,0/(A2:A100>0),A2:A100)

8、不重複個數公式

=SUMPRODUCT(1/COUNTIF(A2:A7,A2:A7))

9、提取唯一值公式

=IFERROR(INDEX(A:A,SMALL(IF(MATCH(A$2:A$7,A$2:A$7,0)=ROW(A$1:A$6),ROW(A$2:A$7)),ROW(A1))),"")

10、中國式排名公式

=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

11、提取字符串任一位中的數字

A1的值為 ABC123.45FE ,截取結果：123.45

數組公式：{=LOOKUP(9^9,MID(A1,MATCH(1,MID(A1,ROW(1:9),1)^0,0),ROW(1:9))*1)}

12、金額大寫轉換公式

=TEXT(LEFT(RMB(A2),LEN(RMB(A2))-3),"[>0][dbnum2]G/通用格式元;[

13、一對多查找包含公式

=COUNT(FIND({"AAA花苑","CCC龍廷"},A2))

14、Vlookup多表查找公式

工資表模板中，每個部門一個表。

在查詢表中，要求根據提供的姓名，從銷售~綜合5個工作表中查詢該員工的基本工資。

方法1：

=IFERROR(VLOOKUP(A2,服務!A:G,7,0),IFERROR(VLOOKUP(A2,人事!A:G,7,0),IFERROR(VLOOKUP(A2,綜合!A:G,7,0),IFERROR(VLOOKUP(A2,財務!A:G,7,0),IFERROR(VLOOKUP(A2,銷售!A:G,7,0),"無此人信息")))))

方法2

=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"銷售";"服務";"人事";"綜合";"財務"}&"!a:a"),A2),{"銷售";"服務";"人事";"綜合";"財務"})&"!a:g"),7,0)

15、Sumif多表求和公式

工作表名稱常常是不規則的，如下圖所示

分析：

首先我們需要用宏表函數取得表名

公式 - 名稱管理器 - 新建名稱 - 在新建名稱中輸入名稱「sh」，然後「引用位置」框中輸入公式：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(now())

最終公式為：

=SUMPRODUCT((SUMIF(INDIRECT(sh&"!b:b"),D2,INDIRECT(sh&"!c:c"))))

16、篩選後連續序號公式

插入輔助列，輸入公式 =1。加入這列是方便在序號列使用公式統計行數。

在序號列輸入公式

=SUBTOTAL(2,B$1:B2)

蘭色說：16個公式，從收集和整理蘭色花費了幾個小時，希望能對同學有用。如果覺得好用，一定記得分享到朋友圈哦，這也是對蘭色最大的支持和鼓勵。